colorMode() \ Language (API) \ Processing 1.0
Author: Casey Reas & Ben Fry
Description: Processing is an electronic sketchbook for developing ideas. It is a context for learning fundamentals of computer programming within the context of the electronic arts.
Keywords: Processing, Processing, Interactive Media, Electronic Arts, Programming, Java, Ben Fry, Casey Reas

Reference for Processing version 1.5. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, please let us know. If you prefer a more technical reference, visit the Processing Javadoc.

Name | ### colorMode()
Examples |
    noStroke();
    colorMode(RGB, 100);
    for (int i = 0; i < 100; i++) {
      for (int j = 0; j < 100; j++) {
        stroke(i, j, 0);
        point(i, j);
      }
    }
    noStroke();
    colorMode(HSB, 100);
    for (int i = 0; i < 100; i++) {
      for (int j = 0; j < 100; j++) {
        stroke(i, j, 100);
        point(i, j);
      }
    }
    // If the color is defined here, it won't be
    // affected by the colorMode() in setup().
    // Instead, just declare the variable here and
    // assign the value after the colorMode() in setup()
    //color bg = color(180, 50, 50);  // No
    color bg;  // Yes, but assign it in setup()

    void setup() {
      size(100, 100);
      colorMode(HSB, 360, 100, 100);
      bg = color(180, 50, 50);
    }

    void draw() {
      background(bg);
    }
Description | Changes the way Processing interprets color data. By default, the parameters for fill(), stroke(), background(), and color() are defined by values between 0 and 255 using the RGB color model. The colorMode() function is used to change the numerical range used for specifying colors and to switch color systems. For example, calling colorMode(RGB, 1.0) will specify that values are specified between 0 and 1. The limits for defining colors are altered by setting the parameters range1, range2, range3, and range 4.
Syntax |
    colorMode(mode);
    colorMode(mode, range);
    colorMode(mode, range1, range2, range3);
    colorMode(mode, range1, range2, range3, range4);
Parameters |
mode | Either RGB or HSB, corresponding to Red/Green/Blue and Hue/Saturation/Brightness
range | int or float: range for all color elements
range1 | int or float: range for the red or hue depending on the current color mode
range2 | int or float: range for the green or saturation depending on the current color mode
range3 | int or float: range for the blue or brightness depending on the current color mode
range4 | int or float: range for the alpha
Returns | None
Usage | Web & Application
Related | background() fill() stroke()

Updated on August 30, 2010 04:29:39pm EDT